Mathématiques 2016 - 2017 Exercice Satellite Scilab Ma350 – UVSQ

Mathématiques
 - Exercice Satellite Scilab Ma350 – UVSQ
Exercice .
Un satellite Sest mis en service. Il est lancé (à partir
d’une fusée) à une hauteur de 100 km au-dessus de la
surface de la terre ; le vecteur vitesse initial est ortho-
gonal à (OS)où Oest le centre de la terre. Calculer sa
trajectoire sur une journée et tracer celle-ci pour les vi-
tesses initiales suivantes : 8000 m/s et 10000 m/s. Cal-
culer l’apogée de la trajectoire, c’est-à-dire l’éloignement
maximal de la terre. Donner aussi le temps d’une pé-
riode (un tour complet). Que se passe-t-il pour une vi-
tesse initiale de 12000 m/s ?
Indications : On assimilera la terre et le satellite à des
points. Rayon de la terre = 6400 km. Constante de gravi-
tation universelle : G= 6.67 ×10−11 . Masse de la terre :
M= 5.972 ×1024 kg.
www.mathoman.com 

Exercice Satellite Scilab Ma350 – UVSQ  -
. Solutions
Solution .
Notons r(t) = −→ OS la position du satellite au temps tet
r=krk. D’après la loi fondamentale de la dynamique, on
a
m¨ r=−GmM
r2
r
r,
où mest la masse du satellite. La trajectoire du satellite
aura lieu dans un plan, à savoir le plan déterminé par le
centre de la terre O, la position initiale du satellite r(0) et
son vecteur vitesse initial v(0). Dans ce plan on travaille
avec le repère orthogonal suivant : son origine est Oet
ses vecteurs sont colinéaires à r(0) respectivement ˙ r(0), et
normés de longueur 1mètre. Notons (x, y)les coordon-
nées associées à ce repère. Ainsi r=px2+y2et on a le
système d’équations différentielles
®¨x=−GM(x2+y2)−3/2x
¨y=−GM(x2+y2)−3/2y.
Pour traiter ce système d’ordre 2avec deux fonctions
inconnues avec Scilab on le transforme en un système
d’ordre 1avec quatre fonctions inconnues. En posant
(z1, z2, z3, z4) = (x, y, ˙x, ˙y)on obtient
˙z1=z3
˙z2=z4
˙z3=−GM(z2
1+z2 2)−3/2z1
˙z4=−GM(z2
1+z2 2)−3/2z2.
On prend comme unités mètres, secondes, kilogrammes
et on entre le membre droit du système différentiel.
M=5.972E24
G=6.67E-11
function d=sat(t,z)
d(1)=z(3)
d(2)=z(4)
d(3)=-G*M*(z(1)^2+z(2)^2)^(-3/2)*z(1)
d(4)=-G*M*(z(1)^2+z(2)^2)^(-3/2)*z(2)
endfunction
Résolution du problème de Cauchy, pour les vitesses ini-
tiales de 8000 m/s et 10000 m/s. On fait la simulation sur
la durée d’un jour, avec un pas de 30 secondes :
initA=[65E5;0;0;8E3]
initB=[65E5;0;0;10E3]
temps=0:30:24*60*60;
solA=ode(initA,0,temps,sat);
solB=ode(initB,0,temps,sat);
On affiche la trajectoire dans la fenêtre numéro 0 :
scf(0), clf(0)
plot2d(solA(1,:),solA(2,:))
plot2d(solB(1,:),solB(2,:))
plot2d(0,0,-3)
xstring(0,0,"Terre")
plot2d(65E5,0,-3)
xstring(65E5,0,"Départ")
La trajectoire semble se refermer sur elle-même. Ce sont
des ellipses. Pour chercher l’apogée on fait une boucle qui
s’arrête dès que la distance du satellite commence à dimi-
nuer :
k=2
while solA(1,k)^2+solA(2,k)^2>
solA(1,k-1)^2+solA(2,k-1)^2;
k=k+1;
end
kk=k-1
DmaxA=sqrt(solA(1,kk)^2+solA(2,kk)^2);
disp([kk,DmaxA])
Conclusion : Pour la vitesse initiale de 8000 m/s l’apo-
gée est à environ 7103 km du centre de la terre. kk = 94.
Donc il est atteint après 93 fois 30 secondes. Donc la pé-
riode est de 93 minutes (environ). De même, le calcul sui-
vant montre que, pour la vitesse initiale de 10000 m/s, on
trouve comme apogée 28807 km et 390 minutes comme
période.
k=2
while solB(1,k)^2+solB(2,k)^2>
solB(1,k-1)^2+solB(2,k-1)^2;
k=k+1;
end
nn=k-1
DmaxB=sqrt(solB(1,nn)^2+solB(2,nn)^2);
disp([nn,DmaxB])
Faisons une vérification graphique dans une deuxième fe-
nêtre :
scf(1), clf(1)
plot2d(solA(1,1:94),solA(2,1:94))
plot2d(solB(1,1:390),solB(2,1:390))
plot2d(solA(1,kk),solA(2,kk),-4)
plot2d(solB(1,nn),solB(2,nn),-4)
plot2d(0,0,-3)
xstring(0,0,"Terre")
plot2d(65E5,0,-3)
xstring(65E5,0,"Départ")
Enfin, pour la vitesse initiale de 12000 m/s le satellite re
revient plus :
initC=[65E5;0;0;12E3]
temps=0:30:5*60*60;
solC=ode(initC,0,temps,sat)
scf(2), clf(2)
plot2d(solC(1,:),solC(2,:))
plot2d(0,0,-3)
xstring(0,0,"Terre")
plot2d(65E5,0,-3)
xstring(65E5,0,"Départ")
www.mathoman.com 